chezmoi: zsh, starship

dot_config/zsh/dot_zshenv

@@ -0,0 +1,173 @@
+# $DOTFILES/tools/zsh/zshenv
+# Date: 2024-11-30
+# Author: js0ny
+# User-specific environment variables for zsh 用户级别的 zsh 环境变量
+
+# Location:
+# $ZDOTDIR/.zshenv (specified by ZDOTDIR)
+# ~/.zshenv (default location)
+# Linking:
+# ln -sf $DOTFILES/tools/zsh/zshenv $ZDOTDIR/.zshenv
+# This file is sourced by all zsh sessions upon startup.
+
+# For me (this user), define XDG Base Directory Specification variables
+# and some configs that does not obey XDG Base Directory Specification
+# but can be configured(by setting the variables) to (just like) obey it.
+# 在此定义 XDG 基础目录规范变量和一些不遵循 XDG 基础目录规范的配置，
+# 使得他们可以通过设置变量来遵循 XDG 基础目录规范。
+
+# XDG Base Directory Specification
+export XDG_CONFIG_HOME="${XDG_CONFIG_HOME:-$HOME/.config}"
+export XDG_DATA_HOME="${XDG_DATA_HOME:-$HOME/.local/share}"
+export XDG_STATE_HOME="${XDG_STATE_HOME:-$HOME/.local/state}"
+export XDG_CACHE_HOME="${XDG_CACHE_HOME:-$HOME/.cache}"
+export XDG_RUNTIME_DIR="/run/user/$(id -u)"
+# Disable shell sessions on macOS when using default terminal
+SHELL_SESSIONS_DISABLE=1
+
+# Zsh # Redefine to make sure it's in $XDG_CONFIG_HOME
+export ZDOTDIR="${XDG_CONFIG_HOME}/zsh"
+
+# Tools Related Environment Variables
+export PAGER="less -R"
+export EDITOR="nvim"
+export VISUAL="nvim"
+
+export GHCUP_USE_XDG_DIRS=1
+export RUSTUP_HOME="$XDG_DATA_HOME"/rustup
+
+# Minimal PATH for early commands
+export PATH="$HOME/.local/bin:/opt/share/bin:/usr/local/bin:/usr/bin:/bin:/usr/sbin:/sbin:$PATH"
+
+if [ -d "/opt/homebrew/bin" ]; then # macOS
+  export PATH="/opt/homebrew/bin:$PATH"
+elif [ -d "/home/linuxbrew/.linuxbrew/bin" ]; then # Linux
+  export PATH="/home/linuxbrew/.linuxbrew/bin:$PATH"
+fi
+
+# macOS Specific
+# This syntax is POSIX standard, for portability
+if [ "$(uname)" = "Darwin" ]; then
+
+fi
+
+# Linux Specific
+if [ "$(uname)" = "Linux" ]; then
+  # CUDA
+  export CUDA_CACHE_PATH="$XDG_CACHE_HOME"/nv
+fi
+
+# Azure CLI
+if command -v az >/dev/null; then
+  export AZURE_CONFIG_DIR="$XDG_DATA_HOME"/azure
+fi
+# Bun JS
+# mv ~/.bun $XDG_DATA_HOME/bun
+# ln -sf $XDG_DATA_HOME/bun/bin/bun ~/.local/bin/bun
+if command -v bun >/dev/null; then
+  export BUN_INSTALL="$XDG_DATA_HOME"/bun
+  export PATH="$BUN_INSTALL/bin:$PATH"
+  [ -s "$BUN_INSTALL/_bun" ] && source "$BUN_INSTALL/_bun"
+fi
+# Cargo
+if command -v cargo >/dev/null; then
+  export CARGO_HOME="$XDG_DATA_HOME"/cargo
+  export PATH="$CARGO_HOME/bin:$PATH"
+fi
+# CGDB
+if command -v cgdb >/dev/null; then
+  export CGDB_DIR="$XDG_CONFIG_HOME"/cgdb
+fi
+# .NET
+if command -v dotnet >/dev/null; then
+  export DOTNET_CLI_HOME="$XDG_DATA_HOME"/dotnet
+  export PATH="$DOTNET_CLI_HOME/.dotnet/tools:$PATH"
+fi
+# Docker
+if command -v docker >/dev/null; then
+  export DOCKER_CONFIG="$XDG_CONFIG_HOME"/docker
+fi
+# GnuPG
+if command -v gpg >/dev/null; then
+  export GNUPGHOME="$XDG_DATA_HOME"/gnupg
+fi
+# Go
+if command -v go >/dev/null; then
+  export GOPATH="$XDG_DATA_HOME"/go
+  export PATH="$GOPATH/bin:$PATH"
+fi
+# Julia
+if command -v julia >/dev/null; then
+  export JULIA_DEPOT_PATH="$XDG_DATA_HOME/julia:$JULIA_DEPOT_PATH"
+fi
+# Node.js
+if command -v node >/dev/null; then
+  export NODE_REPL_HISTORY="$XDG_STATE_HOME"/node/repl_history
+  export TS_NODE_REPL_HISTORY="$XDG_STATE_HOME"/node/ts_node_repl_history
+  export NPM_CONFIG_USERCONFIG="$XDG_CONFIG_HOME"/npm/npmrc
+  export NPM_CONFIG_INIT_MODULE="$XDG_CONFIG_HOME"/npm/config/npm-init.js
+  export NPM_CONFIG_CACHE="$XDG_CACHE_HOME"/npm
+  export NPM_CONFIG_TMP="$XDG_RUNTIME_DIR"/npm
+fi
+# Parallel
+if command -v parallel >/dev/null; then
+  export PARALLEL_HOME="$XDG_CONFIG_HOME"/parallel
+fi
+# Python
+# Works only with Python 3.13.0a3 and later
+if command -v python3 >/dev/null; then
+  export PYTHON_HISTORY="$XDG_DATA_HOME"/python/history
+fi
+# GNU Screen
+if command -v screen >/dev/null; then
+  export SCREENRC="$XDG_CONFIG_HOME"/screen/screenrc
+  export SCREENDIR="${XDG_RUNTIME_DIR}/screen"
+fi
+# Ruby Gem
+# Ruby Gem
+if command -v gem >/dev/null; then
+  setopt nullglob
+  for dir in "$HOME/.local/share/gem/ruby/"*/bin; do
+    if [ -d "$dir" ]; then
+      export PATH="$dir:$PATH"
+    fi
+  done
+  unsetopt nullglob
+fi
+# Spacemacs
+if command -v emacs >/dev/null; then
+  export SPACEMACSDIR="$XDG_CONFIG_HOME"/spacemacs
+fi
+# Fzf
+# This will make shell integration buggy
+# if command -v fzf > /dev/null; then
+#   export FZF_DEFAULT_OPTS_FILE="$HOME/.dotfiles/common/fzfrc"
+# fi
+# tldr
+# Works only with C client (did not verify)
+if command -v tldr >/dev/null; then
+  export TLDR_CACHE_DIR="$XDG_CACHE_HOME"/tldr
+fi
+# W3M
+if command -v w3m >/dev/null; then
+  export W3M_DIR="$XDG_DATA_HOME"/w3m
+fi
+# Wakatime
+if command -v wakatime >/dev/null; then
+  export WAKATIME_HOME="$XDG_CONFIG_HOME/wakatime"
+fi
+# Wget
+if command -v wget >/dev/null; then
+  alias wget='wget --hsts-file="$XDG_CACHE_HOME/wget-hsts"'
+fi
+# z
+if command -v z >/dev/null; then
+  export _Z_DATA="$XDG_DATA_HOME/z"
+fi
+# zsh .zcompdump
+# compinit -d "$XDG_CACHE_HOME"/zsh/zcompdump-"$ZSH_VERSION"
+# Vcpkg
+if command -v vcpkg >/dev/null; then
+  export VCPKG_ROOT="$XDG_DATA_HOME"/vcpkg
+fi
+

dot_config/zsh/dot_zshrc

@@ -0,0 +1,37 @@
+# $DOTFILES/tools/zsh/common.zshrc
+# Date: 2024-11-30
+# Author: js0ny
+# This is the entry point for all zsh configuration files
+# 这是所有zsh配置文件的入口点
+
+# Location: $ZDOTDIR/.zshrc (default: $HOME/.zshrc)
+# Linking:
+# ln -sf $DOTFILES/tools/zsh/common.zshrc $ZDOTDIR/.zshrc
+
+export DOTFILES=$HOME/.dotfiles
+
+case "$(uname)" in
+  Linux)
+    if grep -q Microsoft /proc/version || [[ -n "$WSL_DISTRO_NAME" ]]; then
+      # WSL-specific configuration
+      source "$DOTFILES/platforms/wsl/zshrc"
+    else
+      # Native Linux configuration
+      source "$DOTFILES/platforms/linux/zshrc"
+    fi
+    ;;
+  Darwin)
+    # macOS-specific configuration
+    source "$DOTFILES/platforms/mac/zshrc"
+    ;;
+    #   CYGWIN*|MINGW*|MSYS*)
+    #     source "$DOTFILES/platform/wsl.zsh"
+    #     ;;
+esac
+
+for file in $DOTFILES/tools/zsh/mod/*.zsh; do
+  source $file
+done
+
+[ -f "/home/js0ny/.local/share/ghcup/env" ] && . "/home/js0ny/.local/share/ghcup/env" # ghcup-env
+. "/home/js0ny/.deno/env"

dot_config/zsh/global.zshenv

@@ -0,0 +1,23 @@
+# $DOTFILES/tools/zsh/global.zshenv
+# Date: 2024-11-30
+# Author: js0ny
+# $DOTFILES/tools/zsh/global.zshenv
+# system-wide zshenv file 系统级别的 zshenv 文件，用于设置全局环境变量
+
+# Location:
+# /etc/zshenv: (macOS and some distro)
+# /etc/zsh/zshenv: (some distro)
+# Linking:
+# sudo cp $DOTFILES/tools/zsh/global.zshenv /etc/zshenv # or /etc/zsh/zshenv
+
+# Set ZDOTDIR to $HOME/.config/zsh if it exists
+# This allows us to keep our zsh configuration in $HOME/.config/zsh
+# and zshenv will be located at $HOME/.config/zsh/.zshenv instead of
+# $HOME/.zshenv
+# 如果存在 $HOME/.config/zsh 目录，则将 ZDOTDIR 设置为 $HOME/.config/zsh
+# 防止 .zshenv 文件自动生成在用户目录下
+
+# Ensure SPACE between [ and -d and ]
+if [ -d $HOME/.config/zsh ]; then
+  export ZDOTDIR=$HOME/.config/zsh
+fi

dot_config/zsh/mod/alias.zsh

@@ -0,0 +1,115 @@
+# $DOTFILES/tools/zsh/mod/alias.zsh
+# Date: 2024-11-30
+# Author: js0ny
+# Sourced by user's zshrc 在用户的 zshrc 中被引用
+
+# PowerShell Equivalent, for cross-platform compatibility
+alias ni=touch
+alias cls=clear
+alias ii=open
+
+# Editors #
+alias v=nvim
+alias c=code
+# Use neovide as gVim
+alias gvi="neovide"
+alias svi="sudo vim -u ~/.dotfiles/common/vim.noxdg.vimrc" # Prevent conflicts with svelte-cli
+alias sn="sudo nvim -u ~/.config/nvim/init.lua"
+
+# Dev #
+alias gpp='g++ -std=c++2b' # Set the default C++ standard to C++20
+alias gcc='gcc -std=c99'   # Set the default C standard to C99
+alias cl='clang -std=c99'
+alias clpp='clang++ -std=c++2b'
+alias python=python3 # Set the default Python version to Python 3
+alias py=python
+alias ipy=ipython
+
+alias g=lazygit
+
+alias doomrc="emacsclient -t ~/.config/doom/"
+
+# lsd - modern ls
+if command -v lsd >/dev/null 2>&1; then
+  alias ls='lsd'
+  alias l='lsd -lah'
+  alias ll='lsd -l'
+  alias la='lsd -A'
+  alias l.='lsd -d .*'
+  alias tree='lsd --tree -A'
+else
+  alias l='ls -lah'
+  alias ll='ls -l'
+fi
+
+# Functions #
+mkcd() {
+  mkdir -p $1 && cd $1
+}
+cdls() {
+  cd $1 && ls
+}
+tc() {
+  touch $1 && code $1
+}
+tv() {
+  touch $1 && nvim $1
+}
+mt() {
+  mkdir -p $(dirname $1) && touch $1
+}
+mtv() {
+  mkdir -p $(dirname $1) && touch $1 && nvim $1
+}
+
+alias update="source $DOTFILES/scripts/update.zsh"
+
+if command -v pacman >/dev/null 2>&1; then
+  alias pac="sudo pacman"
+  alias paci="sudo pacman -S"
+  alias pacr="sudo pacman -R"
+  alias pacu="sudo pacman -Syu"
+  alias pacl="pacman -Q"
+  if command -v paru >/dev/null 2>&1; then
+    alias pacs="paru -Ss"
+  elif command -v yay >/dev/null 2>&1; then
+    alias pacs="yay -Ss"
+  else
+    alias pacs="pacman -Ss"
+  fi
+fi
+
+if command -v apt >/dev/null 2>&1; then
+  alias apt="sudo apt"
+  alias apti="sudo apt install"
+  alias aptr="sudo apt remove"
+  alias aptu="sudo apt update && sudo apt upgrade"
+  alias apts="apt search"
+  alias aptl="apt list --installed"
+fi
+
+if command -v brew >/dev/null 2>&1; then
+  alias brewi="brew install"
+  alias brewr="brew uninstall"
+  alias brewu="brew update && brew upgrade"
+  alias brews="brew search"
+  alias brewl="brew list"
+fi
+
+# `-s` suffix alias
+# % readme.md -> glow readme.md
+alias -s {md,markdown}=glow
+alias -s {htm,html,css,scss,js,jsx,ts,tsx,json,jsonc}=code
+alias -s {py,rb,pl,php,java,c,cpp,h,hpp}=nvim
+alias -s {cs,csx,fs,fsx,razor}=code
+
+# TODO: Does not work
+if [ "$TERM" = "xterm-ghostty" ] || [ "$TERM" = "xterm-kitty" ]; then
+  alias icat="kitten icat"
+elif [ "$TERM_PROGRAM" = "WezTerm" ]; then
+  if [ -n "$WSL_DISTRO_NAME" ]; then
+    alias icat="wezterm.exe imgcat"
+  else
+    alias icat="wezterm imgcat"
+  fi
+fi

dot_config/zsh/mod/config.zsh

@@ -0,0 +1,43 @@
+# $DOTFILES/tools/zsh/mod/config.zsh
+# Date: 2024-11-30
+# Author: js0ny
+# Sourced by user's zshrc 在用户的 zshrc 中被引用
+
+# ZSH Config, no need to `export` these variables
+HISTFILE="$XDG_STATE_HOME"/zsh/history
+HIST_STAMPS="yyyy-mm-dd"
+HISTSIZE=10000
+SAVEHIST=10000
+
+export LANG=zh_CN.UTF-8
+export LC_ALL=zh_CN.UTF-8
+
+# Manually manage plugins 手动管理插件
+# Load zsh-syntax-highlighting before zsh-history-substring-search
+# Reference: https://github.com/zsh-users/zsh-history-substring-search?tab=readme-ov-file#usage
+plugins=(
+  "zsh-autosuggestions"
+  "zsh-syntax-highlighting"
+  "zsh-history-substring-search"
+  "zsh-completions"
+)
+
+plugin_dir="$ZDOTDIR/plugins"
+
+for plugin in "${plugins[@]}"; do
+  plugin_path="$plugin_dir/$plugin/$plugin.zsh"
+  plugin_path_alt="$plugin_dir/$plugin/$plugin.plugin.zsh"
+  if [[ -f $plugin_path ]]; then
+    source "$plugin_path"
+  elif [[ -f $plugin_path_alt ]]; then
+    source "$plugin_path_alt"
+  else
+    echo "Warning: Plugin not found: $plugin_path"
+  fi
+done
+
+# https://unix.stackexchange.com/questions/33994/
+# Use `set -k` to mark leading `#` as a comment character
+set -k
+
+source <(fzf --zsh)

dot_config/zsh/mod/env.zsh

@@ -0,0 +1,10 @@
+# $DOTFILES/tools/zsh/mod/env.zsh
+# Date: 2024-11-30
+# Author: js0ny
+# Sourced by user's zshrc 在用户的 zshrc 中被引用
+
+# This file stores only environment variables that only called by
+# interactive session.
+# 这个文件只存储只在交互式会话中调用的环境变量。
+
+export IPYTHONDIR="$XDG_CONFIG_HOME"/ipython

dot_config/zsh/mod/keymap.zsh

@@ -0,0 +1,50 @@
+# $DOTFILES/tools/zsh/mod/keymap.zsh
+# Date: 2024-11-30
+# Author: js0ny
+# Sourced by user's zshrc 在用户的 zshrc 中被引用
+
+# read key: `fish_key_reader`
+# get current bindings: `bindkey`
+
+bindkey -v # Vi Keybindings
+
+# Colemak hnei
+#         ^
+#         n
+#   < h       i >
+#         e
+#         v
+# bindkey -M vicmd 'h' vi-backward-char # No change
+# bindkey -M vicmd 'n' down-line-or-history
+# bindkey -M vicmd 'e' up-line-or-history
+# bindkey -M vicmd 'i' vi-forward-char
+#
+# # Similar position to [i] in QWERTY
+# bindkey -M vicmd 'l' vi-insert
+# bindkey -M vicmd 'L' vi-insert-bol
+# # Ne{[k]s}t
+# bindkey -M vicmd 'k' vi-repeat-search
+# bindkey -M vicmd 'K' vi-rev-repeat-search
+# # [J]ump
+# bindkey -M vicmd 'j' vi-forward-word-end
+# bindkey -M vicmd 'J' vi-forward-blank-word-end
+# # Use N to Join
+# bindkey -M vicmd 'N' vi-join
+
+# Emacs Hybrid
+bindkey '^A' beginning-of-line
+bindkey '^E' end-of-line
+bindkey '^F' forward-char
+bindkey '^B' backward-char
+bindkey '^P' up-line-or-history
+bindkey '^N' down-line-or-history
+bindkey '^R' history-incremental-search-backward
+bindkey '^K' kill-line
+# Zsh will parse <C-Backspace> to C-h
+bindkey '^H' backward-kill-word
+
+# LEADER CONVENTION
+# ^X defines as a prefix key in shell
+# ^A defines as a prefix key in tmux
+# ^B defines as a prefix key in Terminal Emulators
+# SPC defines as a prefix key in nvim

dot_config/zsh/mod/navi.zsh

@@ -0,0 +1,38 @@
+# $DOTFILES/tools/zsh/mod/navi.zsh
+# Date: 2024-12-01
+# Author: js0ny
+# Sourced by user's zshrc 在用户的 zshrc 中被引用
+
+# Define __CD_CMD as "cd" by default
+__CD_CMD="cd"
+
+# If zoxide is available, use it
+if command -v zoxide >/dev/null; then
+  __CD_CMD="z"
+  eval "$(zoxide init zsh)"
+fi
+
+# Define aliases for quick navigation
+alias ..="$__CD_CMD .."
+alias ...="$__CD_CMD ../.."
+alias ....="$__CD_CMD ../../.."
+alias .....="$__CD_CMD ../../../.."
+alias ......="$__CD_CMD ../../../../.."
+
+# Abbreviation for "cd -"
+alias - "$__CD_CMD -"
+
+# Define zls function for cd + ls
+zls() {
+  "$__CD_CMD" "$1" && ls
+}
+alias cdls=zls
+
+# Quick Jump Directories
+[[ -d "$DOTFILES" ]] && alias dot="$__CD_CMD $DOTFILES"
+[[ -d "$HOME/Downloads" ]] && alias down="$__CD_CMD $HOME/Downloads"
+[[ -d "$HOME/.config" ]] && alias conf="$__CD_CMD $HOME/.config"
+[[ -d "$HOME/Obsidian" ]] && alias ob="$__CD_CMD $HOME/Obsidian"
+[[ -d "$HOME/Source" ]] && alias src="$__CD_CMD $HOME/Source"
+[[ -d "$HOME/Source/Scripts" ]] && alias scr="$__CD_CMD $HOME/Source/Scripts"
+[[ -d "$HOME/OrgFiles" ]] && alias org="$__CD_CMD $HOME/OrgFiles"

dot_config/zsh/mod/prompt.zsh

@@ -0,0 +1,6 @@
+# $DOTFILES/tools/zsh/mod/prompt.zsh
+# Date: 2024-11-30
+# Author: js0ny
+# Sourced by user's zshrc 在用户的 zshrc 中被引用
+
+eval "$(starship init zsh)"